unit Cache;

////////////////////////////////////////////////////////////////////////////////////////////////////
interface
uses
  System.Generics.Collections;

type
  TCache<T> = class
  private
    FRoots: TDictionary<string,string>;
    FInfos: TDictionary<string,T>;
  public
    constructor Create;
    destructor  Destroy; override;

    function  GetAssociatedRoot(const Dir: string): string;
    procedure SetAssociatedRoot(const Dir, RootDir: string);
    function  GetInfo(const RootDir: string; out Repo: T): Boolean;
    procedure SetInfo(const RootDir: string; const Info: T);
  end;


////////////////////////////////////////////////////////////////////////////////////////////////////
implementation
uses
  u_FinalPathName;

const
  cLockTimeout = 1000;

{ TCache<T> }

constructor TCache<T>.Create;
begin
  FRoots := TDictionary<string,string>.Create;
  FInfos := TDictionary<string,T>.Create;
end;

destructor TCache<T>.Destroy;
begin
  FRoots.Free;
  FInfos.Free;
  inherited;
end;

function TCache<T>.GetInfo(const RootDir: string; out Repo: T): Boolean;
begin
  Result := TMonitor.Enter(FInfos, cLockTimeout);
  if Result then
  try
    Result := FInfos.TryGetValue(RootDir, Repo) or FInfos.TryGetValue(GetFinalPathName(RootDir), Repo);
  finally
    TMonitor.Exit(FInfos);
  end;
end;

function TCache<T>.GetAssociatedRoot(const Dir: string): string;
begin
  if TMonitor.Enter(FRoots, cLockTimeout) then begin
    try
      if not (FRoots.TryGetValue(Dir, Result) or FRoots.TryGetValue(GetFinalPathName(Dir), Result)) then
          Result := '';
    finally
      TMonitor.Exit(FRoots);
    end;
  end else begin
    Result := '';
  end;
end;

procedure TCache<T>.SetInfo(const RootDir: string; const Info: T);
begin
  TMonitor.Enter(FInfos);
  try
    FInfos.AddOrSetValue(GetFinalPathName(RootDir), Info);
  finally
    TMonitor.Exit(FInfos);
  end;
end;

procedure TCache<T>.SetAssociatedRoot(const Dir, RootDir: string);
var
  FinalDir: string;
begin
  TMonitor.Enter(FRoots);
  try
    FinalDir := GetFinalPathName(Dir);
    if RootDir = '' then begin
      FRoots.Remove(FinalDir);
    end else begin
      FRoots.AddOrSetValue(GetFinalPathName(Dir), RootDir);
    end;
  finally
    TMonitor.Exit(FRoots);
  end;
end;

end.